random(Module,Module) -- make a random module map

Synopsis

Usage:
f = random(F,G)
Function: random
Inputs:
- F, a module, a free module
- G, a module, a free module
Outputs:
- f, a matrix, a random, graded, degree 0 map, from G to F
Optional inputs:
- MaximalRank => default value false, whether to ensure that the resulting map has maximal rank: designed mostly for use with matrices of numbers: for polynomial rings, returns inhomogeneous results
- Density => a real number, default value 1, the proportion of entries to set
- UpperTriangular => a Boolean value, default value false, whether to set just entries strictly above the diagonal
- Height => ..., -- random element of a type

Description

i1 : R = ZZ/101[x,y];

i2 : random(R^{1,2,3},R^{1,2,3})

o2 = {-1} | -26           0      0   |
     {-2} | -29x-42y      47     0   |
     {-3} | 9x2+11xy-22y2 -4x-2y -34 |

             3       3
o2 : Matrix R  <--- R

i3 : random(ZZ^3,ZZ^6,MaximalRank=>true)

o3 = | 475781289856 1923518 549339390083 23779764915332 1994670871310
     | 402159806228 1625877 464335666973 20100129726682 1686019329005
     | 65710116823  265657  75869220268  3284221476233  275483838412 
     ------------------------------------------------------------------------
     4742674908622 |
     4008802494647 |
     655010461421  |

              3        6
o3 : Matrix ZZ  <--- ZZ

i4 : random(ZZ^3,ZZ^10,Density=>.3)

o4 = | 0 0 0 0 8 7 0 0 0 0 |
     | 0 8 3 8 0 2 0 2 5 0 |
     | 0 0 8 0 0 0 0 1 2 0 |

              3        10
o4 : Matrix ZZ  <--- ZZ

i5 : random(ZZ^6,ZZ^6,UpperTriangular=>true)

o5 = | 0 2 2 4 3 7 |
     | 0 0 4 3 6 9 |
     | 0 0 0 3 0 0 |
     | 0 0 0 0 1 2 |
     | 0 0 0 0 0 8 |
     | 0 0 0 0 0 0 |

              6        6
o5 : Matrix ZZ  <--- ZZ

Caveat

Over a polynomial ring, specifying MaximalRank=>true will yield a non-homogeneous matrix.

random(Module,Module) -- make a random module map

Synopsis

Description

Caveat

See also